Должно передаваться одно уведомление со списком всех адресатов, которым невозможно передать сообщение, или отдельные уведомления для каждого из таких адресатов. Из соображений экономии следует, по возможности, использовать первый вариант. Отметим, что основная разница между обработкой псевдонимов (параграф 3.9.1) и пересылкой (данный параграф) состоит в изменении в данном случае обратного адреса. Все уведомления о невозможности доставки передаются с использованием команды MAIL (даже в тех случаях, когда проблема возникла при обработке устаревших команд SEND, SOML или SAML) и должны содержать пустое поле обратного пути (см. параграф 3.6).
Временные метки и пути возврата формально определяются следующим образом (определения FWS и CFWS даны в RFC 5322 [4]):
Return-path-line = "Return-Path:" FWS Reverse-path <CRLF>
Time-stamp-line = "Received:" FWS Stamp <CRLF>
Stamp = From-domain By-domain Opt-info [CFWS] ";" FWS date-time
; date-time определено в RFC 5322 [4], но формы «obs-», особенно для лет,
; обозначенных 2 цифрами, запрещены в SMTP и их использование недопустимо.
From-domain = "FROM" FWS Extended-Domain
By-domain = CFWS "BY" FWS Extended-Domain
Extended-Domain = Domain / ( Domain FWS "(" TCP-info ")" )
/ ( address-literal FWS "(" TCP-info ")" )
TCP-info = address-literal / ( Domain FWS address-literal )
; сервер берет информацию из соединеня TCP, а не из клиентской команды EHLO.
Opt-info = [Via] [With] [ID] [For] [Additional-Registered-Clauses]
Via = CFWS "VIA" FWS Link
With = CFWS "WITH" FWS Protocol
ID = CFWS "ID" FWS ( Atom / msg-id )
; msg-id определено в RFC 5322 [4]
For = CFWS "FOR" FWS ( Path / Mailbox )
Additional-Registered-Clauses = CFWS Atom FWS String
; В этом месте могут добавляться определения из новых
; стандартов, зарегистрированные в IANA. Серверам SMTP
; не следует использовать незарегистрированные имена.
; См. раздел 8.
Link = "TCP" / Addtl-Link
Addtl-Link = Atom
; Дополнительные стандартные имена каналов, зарегистрированные IANA. Via -
; предварительное значение для транспорта, отличного от Internet. Серверам
; SMTP не следует использовать незарегистрированные имена.
Protocol = "ESMTP" / "SMTP" / Attdl-Protocol
Attdl-Protocol = Atom
; Дополнительные стандартные имена для протоколов, зарегистрированных IANA
; в реестре mail parameters [9]. Серверам SMTP не следует использовать
; незарегистрированные имена.